Driven Damped Simple Single Pendulum released from rest

Description

A simple pendulum is driven by an applied torque. What happens as you make the torque stronger?

The parameters we use are: 
(Subscript[ω, 0]) = 3ω/2, where ω is the driving frequency and has been set equal to 2π  for convenience.
β = (Subscript[ω, 0])/4 so that this system is underdamped.
γ is varied.

Angle and Angular Velocity vs time

Manipulate[Module[{eq1,sol,p1},
With[{ω=2π},
eq1=θ''[t]+2β θ'[t]+((ω0)^2)Sin[θ[t]]==γ ((ω0)^2)Cos[ω t];
sol=ParametricNDSolve[{eq1,θ[0]==θ0,θ'[0]==0},{θ,θ'},{t,0,tfinal},{β,ω0,γ,θ0}];
Row@{Column[{Plot[(1/Degree)θ[(((3/2)ω)/4),(3/2)ω,γval,θ0val][t]/.sol,{t,0,tfinal},GridLines->Automatic,AspectRatio->1/3,PlotLabel->Row[{Style["Angle θ (degrees) vs. time",FontSize->14]}],ImageSize->{800,300},PlotRange->All,PlotPoints->100],Plot[θ'[(((3/2)ω)/4),(3/2)ω,γval,θ0val][t]/.sol,{t,0,tfinal},ImageSize->{800,100},AspectRatio->Full,PlotLabel->Style["Angular velocity (OverDot[θ]) vs. time",FontSize->14],PlotPoints->100]}],
Animate[Evaluate@Graphics[
{
{PointSize[0.05],Point[{0,0}]},
{Thickness[.01],Line[{{0,0},{Sin[θ],- Cos[θ]}}]/.{θ->θ[((1.5ω)/4),(3/2)ω,γval,θ0val][t]}/.sol/.t->tcurrent},
{Text[Row[{"Time = ",tcurrent}],{-.8,0.9}]}
},PlotRange->{{-1.1,1.1},{-1.1,1.1}},AspectRatio->Full],{tcurrent,0.1,tfinal},AnimationRepetitions->1,AnimationRate->.5]
}
]
]
,{{γval,0.2,Style["Forcing Magnitude γ",FontSize->14]},0.01,1.2},
{{tfinal,6,Style["Length of simulation",FontSize->14]},3,100,1},
{{θ0val,10 Degree,Style["Initial Angle",FontSize->14]},-90 Degree,90 Degree,5 Degree}
]

Cloud Deploy

URL is at https://www.wolframcloud.com/obj/9cec4503-f3af-44d0-83c4-08800ca24392

(*CloudPublish[]*)